<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">;
; INFO.DEF modified as an example of a Post Card door.
;
;

  LOADMSG "                        Loading Script. Please wait..."

  FIELDS
    Name    .........................     C     @user@
    Company ___......................     C
    Addr1   _____....................     C
    Addr2   .........................     C
    CitySt  _____....................     C     @city@
    Zip     _____                         N
    Country ___......................     C     USA
    Phone   _                             P
    Fax     _                             P
    Age     __                            N
    How     _........................     C
    Occup   _........................     C
    Qantel  _                             L
    QUser   _                             L
    PCOwner _                             L
    PCType  _........................     C
    NetWork _                             L
    NetType _........................     C
    Vt3Emu  _                             L
    EmuSoft __.......................     C
    Cmnt1   ........................................................  C
    Cmnt2   ........................................................  C
    Cmnt3   ........................................................  C
    Option  _                             C
    PEnter  .                             C
    aword   ..............................  C
    Rand    ............... C
    SysDate ..........  C
    SysTime ..........  C
    SysNode ...         C
    DataLun    . N 0
    POST_CARDS . N
    pw      ....    N @security@
  FIELDS

;
;----------------------------------------------------------------------
; Data file format
;----------------------------------------------------------------------

  SET POST_CARDS  1    ;&lt;&lt;--- set to '0' if processing of Post Cards is
                       ;      NOT desired.

  IF POST_CARDS
    FORMAT DataFmt
      Name
      Company
      Addr1
      Addr2
      CitySt
      Zip
      Country
      Phone
      SysDate
      SysTime
      SysNode
      Rand
    FORMAT
  ENDIF


  COLOR BRIGHT CYAN BLACK
  DISPLAY_FILE J:\PCB\INFO.TXT            ;display this file

  INDENT  5
  TEXT  "@X09哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪"
  TEXT  "             **** QExchange Bulletin Board ****"
  TEXT  "@X09哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪"
  TEXT  ""
  TEXT  "You are in the new caller login section. After completing the "
  TEXT  "questions below, you will be returned to the main bulletin board."
  TEXT  ""
  TEXT  "This is a one-time procedure. Estimated time to complete this"
  TEXT  "questionnaire is 2 to 4 minutes."
  TEXT  ""
  TEXT  "  Files uploaded: " @upfiles@
  TEXT  "Files downloaded: " @dlfiles@
  TEXT  ""
  TEXT  "@X09哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪"
  TEXT  ""
  INDENT  0

  BEEPS OFF
  FLUSH_KB
  MIN_ATTR  BRIGHT RED BLACK
  MAX_ATTR  BRIGHT BLUE BLACK
  ANS_ATTR  BRIGHT YELLOW BLACK
  LOGMSG  "@X05" @user@ " accessed InfoDoor"

:Modify
  COLOR BRIGHT CYAN BLACK
  PROMPT "            Name: " Name
  NULL_ENTRY  AbortJob

  PROMPT "         Company: " Company
  PROMPT "  Address line 1: " Addr1
  PROMPT "  Address line 2: " Addr2
  PROMPT "     City, State: " CitySt
  PROMPT "             Zip: " Zip
  PROMPT "         Country: " Country
  PROMPT "    Phone Number: " Phone
  TEXT   "                  (enter 0's if no FAX)"
  PROMPT "      Fax Number: " Fax
  PROMPT "        Your Age: " Age

  NEWLINE
  PROMPT "                Your occupation: " Occup
  PROMPT " How did you hear of QExchange?: " How
  PROMPT "         Are you a Qantel User?: " Qantel
  IF Qantel == "Y"
    PROMPT "Do you subscribe to QUSER NEWS?: " QUser
  ENDIF

  PROMPT "               Do you own a PC?: " PCOwner
  IF PCOwner == "Y"
    PROMPT "                     What Type?: " PCType
  ENDIF

  PROMPT "       Do you use a PC NetWork?: " NetWork
  IF NetWork == "Y"
    PROMPT "                     Which one?: " NetType
  ENDIF

  PROMPT "      Do you use VT3 Emulation?: " Vt3Emu
  IF Vt3Emu == "Y"
    PROMPT "                     Which one?: " EmuSoft
  ENDIF

  NEWLINE
  PROMPT "        Comments: " Cmnt1
  NULL_ENTRY  EndOfJob
  PROMPT "                : " Cmnt2
  NULL_ENTRY  EndOfJob
  PROMPT "                : " Cmnt3


:EndOfJob
  SET Option
  COLOR BRIGHT CYAN BLACK
  TEXT  "哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪哪"
  COLOR BRIGHT YELLOW BLACK
  PROMPT "@X0ECommand: (@X0FA@X0E)ccept, (@X0FL@X0E)ist, (@X0FE@X0E)dit " Option
  UCASE Option
  SWITCH  Option
    CASE  "A"
      GOTO JobOk
      BREAK
    CASE  "L"
      GOTO Listit
      BREAK
    CASE  "E"
      NEWLINE 2
      GOTO Modify TOP
      BREAK
  SWITCH  END
  GOTO EndOfJob TOP

:Listit
  COLOR CYAN BLACK
  TEXT  ""
  TEXT  "                       Name@X08: @X0B" Name
  TEXT  "                    Company@X08: @X0B" Company
  TEXT  "             Address line 1@X08: @X0B" Addr1
  TEXT  "             Address line 2@X08: @X0B" Addr2
  TEXT  "  City, State, Zip, Country@X08: @X0B" CitySt "  " Zip "   " Country
  TEXT  "               Phone Number@X08: @X0B" Phone "      Fax: " Fax
  TEXT  "                   Your Age@X08: @X0B" Age
  TEXT  "                 Occupation@X08: @X0B" Occup
  TEXT  " How you heard of QExchange@X08: @X0B" How
  TEXT  "               Qantel User?@X08: @X0B" Qantel
  TEXT  "     QUSER NEWS subscriber?@X08: @X0B" QUser
  TEXT  "           Do you own a PC?@X08: @X0B" PCOwner
  TEXT  "                 What Type?@X08: @X0B" PCType
  TEXT  "   Do you use a PC NetWork?@X08: @X0B" NetWork
  TEXT  "                 Which one?@X08: @X0B" NetType
  TEXT  "  Do you use VT3 Emulation?@X08: @X0B" Vt3Emu
  TEXT  "                 Which one?@X08: @X0B" EmuSoft
  TEXT  "        Comments@X08: @X0B" Cmnt1
  TEXT  "                @X08: @X0B" Cmnt2
  TEXT  "                @X08: @X0B" Cmnt3
  GOTO EndOfJob TOP


:JobOk
  COLOR BRIGHT WHITE BLACK
  TEXT   ""
  TEXT   "Logging data. Please wait..."
  ;
  LOG_DATA "J:\PCB\INFO.LOG"
    "---------------------------------------------------------------------"
    "Name        : "  Name
    "Company     : "  Company
    "Date        : "  @sysdate@
    "Time        : "  @systime@
    "Node        : "  @node@
    "Addr1       : "  Addr1
    "Addr2       : "  Addr2
    "City, State : "  CitySt "   " Zip
    "Country     : "  Country
    "Phone       : "  Phone
    "Fax         : "  Fax
    "Age         : "  Age
    "How Heard of: "  How
    "Occupation  : "  Occup
    "Qantel User?: "  Qantel
    "Quser News? : "  QUser
    "PC Owner    : "  PCOwner
    "PC Type     : "  PCType
    "NetWork User: "  NetWork
    "NetWare SW  : "  NetType
    "VT3 Emu User: "  Vt3Emu
    "EMU SW Used : "  EmuSoft
    "Comments    : "  Cmnt1
    "            : "  Cmnt2
    "            : "  Cmnt3
  LOG_DATA

  ;
  ;-------------------------------------------------------------------------
  ; Post Card Processing
  ;-------------------------------------------------------------------------
  ;
  IF POST_CARDS
    RANDOM_STR    0 Rand                  ;set some file fields
    SET SysDate   @sysdate@               ;
    SET SysTime   @systime@               ;
    SET SysNode   @node@                  ;
    OPENFILE  DataLun F:\PCB\INFO.DAT     ;data file for VERIFY door
    WRITEFILE DataLun DataFmt             ;write new record
    CLOSEFILE DataLun                     ;close the file

    LOG_DATA "F:\PCB\INFO.POS"            ;create physical Post Card text
      "---------------------------------------------------------------------"
      "Dear " @user@ ","
      "Thank you for calling our system."
      "To gain full access for a 15 day trial, please"
      "enter 'VERIFY' the next time you call our system".
      ""
      "You will be asked for a security code."
      'Your security code is: "' Rand '"'
    LOG_DATA
  ENDIF
  ;
  ;-------------------------------------------------------------------------
  ; END of Post Card Processing
  ;-------------------------------------------------------------------------
  ;

  IF @security@ &lt;= 10
    INCREASE 1 10
  ENDIF

  SEC_TABLE                     ;Security Table Start
     9  10                      ; users at sec level 9 goto 10
    10  20                      ; users at sec level 10 goto 20
    20  30                      ; users at sec level 20 goto 30
  SEC_TABLE                     ;Security Table End
                                ;
                                ;Other security functions:
                                ;
                                ; INCREASE x y
                                ;   Increase sec level by 'x', but do
                                ;   not allow to exceed 'y'.
                                ;
                                ; DECREASE x y
                                ;   Decrease sec level by 'x', but do
                                ;   not allow to be less than 'y'.
                                ;
  SEC_LOOKUP  j:\pcb\info.lck   ;searches this file for the user name.
                                ; if found, it uses the security code
                                ; in this file to override any other
                                ; value. This could be used in a new
                                ; callers script, but have names of
                                ; friends (or customers, or etc..) in
                                ; the file - when looked up, the new
                                ; security is available.
                                ;
  UPDATE_USER_RECORD            ;update the user record with new
                                ; security value.
  IF @firstu@ != "SYSOP"
    MSG
      SYSOP
      SYSOP
      "New User Called"
      Comment
      "Main Board"
      "A new user named " @user@ " has called the system."
      "The date and time was " @sysdate@ " : " @systime@ "."
      "They are from " CitySt "."
      "Their phone number is " Phone
      "Their occupation is " Occup "."
      "They are " Age " years old."
      "Qantel User: " Qantel ".  Vt3 Emu User: " Vt3Emu " " EmuSoft
      ""
      "Node: " @node@ "  Baud Rate: " @bps@
    MSG
  ENDIF
  GOTO EndIt

:AbortJob
  IF @firstu@ != "SYSOP"
    MSG
      SYSOP
      SYSOP
      "New User Abort"
      Comment
      "Main Board"
      "A new user named " @user@ " has called the system."
      "The date and time was " @sysdate@ " : " @systime@ "."
      ""
      "They @X8Caborted@X0B the INFO script."
      ""
      "Node: " @node@ "  Baud Rate: " @bps@
    MSG
  ENDIF

:EndIt
  IF Qantel == "Y"
    IF QUser == "N"
      COLOR BRIGHT CYAN BLACK
      DISPLAY_FILE J:\PCB\QUSER.TXT
    ENDIF
  ENDIF

  EXIT

</pre></body></html>